Auto Generate SQL Variable Syntax for Table Column Names

CREATE TABLE [dbo].[Automobile](
   [EventId] [int] IDENTITY(1,1) NOT NULL,
   [AutomobileId] [nvarchar](50) NULL,
   [Day] [date] NOT NULL,
   [Place] [nvarchar](50) NULL,
   [Amount] [money] NULL,
   [Price] [money] NULL,
   [Odometer] [int] NULL,
   [Comments] [nvarchar](50) NULL,
   [Mileage] [int] NULL,
   [Consumption] [money] NULL,
   [FuelEfficiency]  AS ([Mileage]/[Consumption]),
   [ModifiedDate] [datetime] NULL,
   [ModifiedBy] [nvarchar](50) NULL,
 CONSTRAINT [PK_Automobile] PRIMARY KEY CLUSTERED 
(
   [EventId] ASC
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON, OPTIMIZE_FOR_SEQUENTIAL_KEY = OFF) ON [PRIMARY]
) ON [PRIMARY]
GO

-- ==================================================
-- Author:      Sebastião Pereira - MSSQLTips
-- Create date: 20240723
-- Description: Columns Tool based on Template
-- ==================================================
CREATE PROCEDURE [dbo].[uspTableToModel] 
         (@Schema varchar(50)
         ,@Table varchar(50)
         ,@Template nvarchar(500)
         ,@ShowAsList bit
         ,@ConvertNet bit)
WITH EXECUTE AS CALLER
AS
BEGIN
   SET NOCOUNT ON;
   BEGIN TRY
 
      /* Convention:
         Symbol Column
         {cn} [COLUMN_NAME] 
         {dt} [DATA_TYPE]
      */
 
      IF @ShowAsList = 0 
         SELECT    REPLACE(REPLACE(@Template
                    ,'{cn}',[COLUMN_NAME])
                     ,'{dt}',[dbo].[ufnReturnSqlDataType] ([DATA_TYPE],[CHARACTER_MAXIMUM_LENGTH],@ConvertNet)) AS [Result]
            FROM  [INFORMATION_SCHEMA].[COLUMNS]
            WHERE  [TABLE_SCHEMA] = @Schema AND
                [TABLE_NAME] = @Table;
      ELSE
         SELECT     STRING_AGG(REPLACE(REPLACE(@Template
                     ,'{cn}',[COLUMN_NAME])
                     ,'{dt}',[dbo].[ufnReturnSqlDataType] ([DATA_TYPE],[CHARACTER_MAXIMUM_LENGTH],@ConvertNet)), ',') 
                  WITHIN GROUP (ORDER BY [ORDINAL_POSITION]) AS [Result]
            FROM  [INFORMATION_SCHEMA].[COLUMNS]
            WHERE  [TABLE_SCHEMA] = @Schema AND
                [TABLE_NAME] = @Table;
 
   END TRY
   BEGIN CATCH
      IF @@TRANCOUNT > 0
         BEGIN
            ROLLBACK TRANSACTION;
         END
         
      -- Print error information. 
      PRINT  'Error: ' + CONVERT(varchar(50), ERROR_NUMBER()) +
         ', Severity: ' + CONVERT(varchar(5), ERROR_SEVERITY()) +
         ', State: ' + CONVERT(varchar(5), ERROR_STATE()) + 
         ', Procedure: ' + ISNULL(ERROR_PROCEDURE(), '-') + 
         ', Line: ' + CONVERT(varchar(5), ERROR_LINE()) + 
         ', User: ' + CONVERT(varchar(5), GETDATE());
      PRINT ERROR_MESSAGE();
   END CATCH; 
END
GO

-- ==================================================
-- Author:      Sebastião Pereira - MSSQLTips
-- Create date: 20240723
-- Description: Return SQL Data type
-- ==================================================
CREATE FUNCTION [dbo].[ufnReturnSqlDataType] 
            (@DataType nvarchar(50)
            ,@MaxLength nvarchar(50)
            ,@ConvertToDotNet bit)
RETURNS nvarchar(MAX)
WITH EXECUTE AS CALLER
AS
BEGIN
   DECLARE @Result nvarchar(MAX);
 
   IF @ConvertToDotNet = 1
      BEGIN
         SET @Result =
            CASE 
               WHEN @DataType IN ('bigint') THEN 'long'
               WHEN @DataType IN ('int') THEN 'int'
               WHEN @DataType IN ('smallint') THEN 'short'
               WHEN @DataType IN ('tinyint') THEN 'byte'
               WHEN @DataType IN ('bit') THEN 'boolean'
               WHEN @DataType IN ('decimal','numeric','money','smallmoney') THEN 'decimal'
               WHEN @DataType IN ('float') THEN 'double'
               WHEN @DataType IN ('real') THEN 'single'
               WHEN @DataType IN ('char','nchar','varchar','nvarchar','text','ntext') THEN 'string'
               WHEN @DataType IN ('date','datetime','datetime2','smalldatetime') THEN 'DateTime'
               WHEN @DataType IN ('time') THEN 'TimeSpan'
               WHEN @DataType IN ('datetimeoffset') THEN 'DateTimeOffset'
               WHEN @DataType IN ('binary','varbinary','image','timestamp','rowversion') THEN 'byte[]'
               WHEN @DataType IN ('uniqueidentifier') THEN 'guid'
               WHEN @DataType IN ('xml') THEN 'XmlDocument'
               WHEN @DataType IN ('sql_variant') THEN 'Object'
            END;
      END
   ELSE
      SET @Result = CONCAT(@DataType,'(' + CONVERT(varchar(10),@MaxLength) + ')');
 
   RETURN @Result;
END
GO